X DevAPI User Guide / Expressions EBNF Definitions

Chapter 12 Expressions EBNF Definitions

This section provides a visual reference guide to the grammar for the expression language used in X DevAPI.

ident

ident 
   ::= ID | QUOTED_ID

Figure 12.1 ident

Image shows the syntax in EBNF form as described in the preceding text.

schemaQualifiedIdent

schemaQualifiedIdent 
                  ::= ( ident_schema '.' )? ident

Figure 12.2 schemaQualifiedIdent

columnIdent

Figure 12.3 columnIdent

columnIdent
         ::= ( ident '.' ( ident '.' )? )? ident ( ( '->' | '->>' ) "'" '$' documentPath "'" )?

documentPathLastItem

documentPathLastItem
         ::= '[*]'
           | '[' INT ']'
           | '.*'
           | '.' documentPathMember

Figure 12.4 documentPathLastItem

documentPathItem

documentPathItem
         ::= documentPathLastItem
           | '**'

Figure 12.5 documentPathItem

documentPath

documentPath        
          ::= documentPathItem* documentPathLastItem

Figure 12.6 documentPath

documentField

Figure 12.7 documentField

documentField
         ::= fieldId documentPath*
           | '$' documentPath

argsList

argsList ::= expr ( ',' expr )*

Figure 12.8 argsList

lengthSpec

lengthSpec ::= '(' INT ')'

Figure 12.9 lengthSpec

castType

castType ::= 'SIGNED' 'INTEGER'*
           | 'UNSIGNED' 'INTEGER'*
           | 'CHAR' lengthSpec*
           | 'BINARY' lengthSpec*
           | 'DECIMAL' ( lengthSpec | '(' INT ',' INT ')' )?
           | 'TIME'
           | 'DATE'
           | 'DATETIME'
           | 'JSON'

Figure 12.10 castType

functionCall

functionCall
         ::= schemaQualifiedIdent '(' argsList? ')'

Figure 12.11 functionCall

placeholder

placeholder ::= ':' ID

Figure 12.12 placeholder

groupedExpr

groupedExpr ::= '(' expr ')'

Figure 12.13 groupedExpr

unaryOp

unaryOp  ::= ( '!' | '~' | '+' | '-' ) atomicExpr

Figure 12.14 unaryOp

literal

literal  ::= INT
           | FLOAT
           | STRING_SQ
           | STRING_DQ
           | 'NULL'
           | 'FALSE'
           | 'TRUE'

Figure 12.15 literal

jsonKeyValue

jsonKeyValue ::= STRING_DQ ':' expr

Figure 12.16 jsonKeyValue

jsonDoc

jsonDoc  ::= '{' ( jsonKeyValue ( ',' jsonKeyValue )* )* '}'

Figure 12.17 jsonDoc

jsonarray

jsonArray ::= '[' ( expr ( ',' expr )* )* ']'

Figure 12.18 jsonarray

atomicExpr

atomicExpr
         ::= placeholder
           | columnOrPath
           | functionCall
           | groupedExpr
           | unaryOp
           | castOp

Figure 12.19 atomicExpr

intervalUnit

INTERVAL_UNIT
         ::= 'MICROSECOND'
           | 'SECOND'
           | 'MINUTE'
           | 'HOUR'
           | 'DAY'
           | 'WEEK'
           | 'MONTH'
           | 'QUARTER'
           | 'YEAR'
           | 'SECOND_MICROSECOND'
           | 'MINUTE_MICROSECOND'
           | 'MINUTE_SECOND'
           | 'HOUR_MICROSECOND'
           | 'HOUR_SECOND'
           | 'HOUR_MINUTE'
           | 'DAY_MICROSECOND'
           | 'DAY_SECOND'
           | 'DAY_MINUTE'
           | 'DAY_HOUR'
           | 'YEAR_MONTH'

Figure 12.20 INTERVAL_UNIT

interval

interval ::= 'INTERVAL' expr INTERVAL_UNIT

Figure 12.21 interval

intervalExpr

intervalExpr
         ::= atomicExpr ( ( '+' | '-' ) interval )*

Figure 12.22 intervalExpr

mulDivExpr

mulDivExpr
         ::= intervalExpr ( ( '*' | '/' | '%' ) intervalExpr )*

Figure 12.23 mulDivExpr

addSubExpr

addSubExpr
         ::= mulDivExpr ( ( '+' | '-' ) mulDivExpr )*

Figure 12.24 addSubExpr

shiftExpr

shiftExpr
         ::= addSubExpr ( ( '<<' | '>>' ) addSubExpr )*

Figure 12.25 shiftExpr

bitExpr

bitExpr  ::= shiftExpr ( ( '&' | '|' | '^' ) shiftExpr )*

Figure 12.26 bitExpr

compExpr

compExpr ::= bitExpr ( ( '>=' | '>' | '<=' | '<' | '=' | '<>' | '!=' ) bitExpr )*

Figure 12.27 compExpr

ilriExpr

ilriExpr ::= compExpr 'IS' 'NOT'* ( 'NULL' | 'TRUE' | 'FALSE' )
           | compExpr 'NOT'* 'IN' '(' argsList* ')'
           | compExpr 'NOT'* 'IN' compExpr
           | compExpr 'NOT'* 'LIKE' compExpr ( 'ESCAPE' compExpr )*
           | compExpr 'NOT'* 'BETWEEN' compExpr 'AND' compExpr
           | compExpr 'NOT'* 'REGEXP' compExpr
           | compExpr

Figure 12.28 ilriExpr

andExpr

andExpr  ::= ilriExpr ( ( '&&' | 'AND' ) ilriExpr )*

Figure 12.29 andExpr

orExpr

orExpr   ::= andExpr ( ( '||' | 'OR' ) andExpr )*

Figure 12.30 orExpr

expr

expr     ::= orExpr

Figure 12.31 expr

DIGIT

DIGIT    ::= '0' - '9'

Figure 12.32 DIGIT

FLOAT

FLOAT    ::= DIGIT* '.' DIGIT+ ( 'E' ( '+' | '-' )* DIGIT+ )*
           | DIGIT+ 'E' ( '+' | '-' )* DIGIT+

Figure 12.33 FLOAT

INT

INT      ::= DIGIT+

Figure 12.34 INT

QUOTED_ID

QUOTED_ID
         ::= '`' ID '`'
           | '`' ( '~' '`'* | '``' )* '`'

Figure 12.35 QUOTED_ID

ID

ID       ::= ( 'a' - 'z' | 'A' - 'Z' | '_' ) ( 'a' - 'z' | 'A' - 'Z' | '0' - '9' | '_' )*

Figure 12.36 ID

WS

WS       ::= [ \t\r\n]+

Figure 12.37 WS

SCHAR

SCHAR    ::= [\u0020\u0021\u0023\u0024\u0025\u0026\u0028-\u005B\u005D-\u007E]

Figure 12.38 SCHAR

STRING_DQ

STRING_DQ
         ::= '"' ( SCHAR | "'" | ESCAPED_DQ )* '"'

Figure 12.39 STRING_DQ

STRING_SQ

STRING_SQ
         ::= "'" ( SCHAR | '"' | ESCAPED_SQ )* "'"

Figure 12.40 STRING_SQ

PREV HOME UP NEXT