As a Copybara user, I want to be able to operate on workflows via Bazel targets

[sudoforge]

#146 made it easier to load this workspace into another, which means that it's easier for an external workspace to import the copybara tool and use it via bazel run <label> -- <args>. It'd be far nicer to be able to operate on workflows via bazel targets, something like:

copybara_migrate(
    name = "export_to_foo",
    workflow = ":copy.bara.sky",
    data = [
        "//some/copybara:library",
        ...
    ],
)

which we could then run via bazel run //path/to/target:export_to_foo.

[sudoforge]

As a heads up to anyone watching this issue, I have been developing rules for Copybara for my own personal use for some time now. I hope to be able to submit a CL to this repository with these rules some time in the next few weeks.

[hsudhof]

That sounds great - I have a bazel rule to validate copy.bara.sky files in tests, I see how that could be used to run copybara for migrations.

[sudoforge]

Ooh, that sounds neat. Does that live anywhere I could consume it?

[hsudhof]

Sadly it has a few proprietary bits that I would have to remove, can look into it.

Essentially it is a bazel sh_test rule with copybara as dependency that invokes a shell script to validate a config with a freshly built copybara.

[sudoforge]

Ah, okay. The ruleset I've been working on is a bit more complete, with a toolchain to boot. Adding a test rule should be fairly simple; I'll do that before submitting them here.

[danielepolencic]

@sudoforge is there a PR for the rules?

[sudoforge]

@danielepolencic I never got around to cleaning up my personal rule lib and submitting it for use here. Thanks for the reminder; I'll revisit this when I have the cycles to.

[michaelschiff]

I had this same need, and fwiw the approach I took was:

• build a copy of copybara_deploy.jar and self-host this (private cloud storage bucket)
• declare an http_file in my WORKSPACE referencing this external resource
• create a copybara package declaring a java_import of the http file, and then a set of java_binary targets for each of the external repositories I sync, declared with all necesssary arguments (BUILD file source below)

This is an alternative to pulling in the whole copybara external repo (avoiding potential workspace dependency conflicts) while achieving the same usage as provided by #146

load("@bazel_skylib//rules:common_settings.bzl", "string_flag")
load("@rules_java//java:defs.bzl", "java_binary")

string_flag(
    name = "mode",
    build_setting_default = "dry-run",
)

config_setting(
    name = "publish",
    flag_values = {":mode": "publish"},
)

java_import(
    name = "copybara_lib",
    jars = ["@copybara//file"],
)

[
    java_binary(
        name = "copybara-%s" % REPO,
        args = select({
            ":publish": [
                "migrate",
                "scripts/copybara/copy.bara.sky",
                REPO,
            ],
            "//conditions:default": [
                "migrate",
                "--dry-run",
                "scripts/copybara/copy.bara.sky",
                REPO,
            ],
        }),
        data = [
            "copy.bara.sky",
        ],
        main_class = "com.google.copybara.Main",
        runtime_deps = [":copybara_lib"],
    )
    for REPO in [
        "repo1",
        "repo2",
        "repo3",
        "repo4",
        "repo5",
    ]
]